1. **Пошаговое руководство по созданию http-сервиса.**

**План обучения:**

Подготовка объектов метаданных для сервиса.

1. Создадим чистую базу данных.
2. Добавим в базу данных справочник «Номенклатура»
3. Добавим реквизиты в справочник «Номенклатура»
4. Добавим регистр сведений «Штрих коды»
5. Добавим измерения и ресурсы в регистр сведений «Штрих коды»
6. Добавить общий модуль «Общего назначения»
7. В общем модуле создадим функцию, которая вернет JSON строку с нашими данными
8. Запустим платформу 1С: Предприятие 8 в режиме «предприятие» и заполним данными справочник «Номенклатура» и регистр сведений «Штрих коды»

Создание http сервиса:

1. Открываем дерево метаданных ветка «Общие» - «HTTP-сервисы». Позиционируемся на объекте «HTTP-сервисы»
2. Добавляем новый сервис.
3. Закладка «Основные» поле «Имя». Задаем имя. Имя может быть любым. Желательно чтобы имя сервиса отражало его суть.
4. Закладка «Основные» поле «Корневой URL». Необходимо задать имя корневого url.
5. Закладка «Шаблоны URL». Добавляем новый шаблон. Задаем ему имя. Имя может быть любым. Желательно, чтобы имя отражало предназначение шаблона.
6. В шаблоне добавляем метод. В данном методе будем программный код шаблона.

Публикация http сервиса:

1. ВАЖНО, НА ВАШЕМ КОМПЬЮТЕРЕ УЖЕ ДОЛЖЕН БЫТЬ УСТАНОВЛЕН ВЕБ СЕРВЕР (APACHE (2.2 ИЛИ 2.4) ИЛИ ISS)
2. Запускаем конфигуратор 1С: Предприятия 8 в режиме «Запуск от имени администратора»
3. Главное меню Администрирование – Публикация на веб-сервере
4. Закладка «Основные» поле имя. Необходимо задать имя. Имя должно быть сформировано по правилу формирования имен переменных. Имя не должно содержать русских букв.
5. Закладка «Основные» поле «Каталог». Создаем на жестком диске каталог (например www) и указываем к нему путь. В данный каталог будет размещена публикация.
6. Закладка «Основные» - закладка «HTTP сервисы». Устанавливаем флаг около нашего сервиса.
7. Нажимаем кнопку «Опубликовать». Перезапускаем веб сервер.

Проверка работы http сервиса:



1. Запускаем браузер.
2. Прописываем в строке браузера ip адрес компьютера на котором работает веб сервис (в нашем случае это наша локальная машина)
3. После этого если веб сервер запущен, мы должны увидеть в браузере соответствующее сообщение.

Если все нормально, в строке браузера прописываем путь к нашему сервису по определенному правилу и получаем результат работы сервиса.


**Выполнение пунктов списка**

**Подготовка объектов метаданных**


Создаем чистую базу данных:




**Добавляем в базу данных справочник «Номенклатура»**



**Добавляем реквизит «Артикул» в справочник «Номенклатура»**





**Добавим регистр сведений «Штрихкоды»**




**Добавляем измерение и ресурсы в регистр сведений «Штрихкоды»**

**Измерение «Штрихкод» тип Строка длина Строки 100, ресурс «Номенклатура» ссылка на справочник «Номенклатура»**






**Добавляем общий модуль «ОбщегоНазначения»**



**В общем модуле напишем функцию, которая вернет JSON строку с данными**



Функция ПолучитьНоменклатуру()Экспорт

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| Штрихкоды.Штрихкод КАК barcode,

| Штрихкоды.Номенклатура.Код КАК cod,

| Штрихкоды.Номенклатура.Наименование КАК name,

| Штрихкоды.Номенклатура.Артикул КАК articul

|ИЗ

| РегистрСведений.Штрихкоды КАК Штрихкоды";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Массив = Новый Массив;

Пока Выборка.Следующий()Цикл

Структура = Новый Структура("barcode, cod, name, articul");

ЗаполнитьЗначенияСвойств(Структура, Выборка);

Массив.Добавить(Структура);

КонецЦикла;

ЗаписьJSON = Новый ЗаписьJSON;

ЗаписьJSON.УстановитьСтроку();


ЗаписатьJSON(ЗаписьJSON, Массив);


СтрокаJSON = ЗаписьJSON.Закрыть();

Возврат СтрокаJSON;

КонецФункции

Обновим конфигурацию базы данных. Запустим программу в режиме «Предприятие». Заполним тестовыми данными справочник «Номенклатура» и регистр сведений «Штрихкоды»






**Переходим к следующему пункту**

**Создание http сервиса**


Открываем дерево метаданных ветка «Общие» - «HTTP-сервисы». Позиционируемся на объекте «HTTP-сервисы»

Добавляем новый сервис


Закладка «Основные» поле «Имя». Задаем имя. Имя может быть любым. Желательно чтобы имя сервиса отражало его суть. Закладка «Основные» поле «Корневой URL». Необходимо задать имя корневого url.




Закладка «Шаблоны URL». Добавляем новый шаблон. Задаем ему имя. Имя может быть любым. Желательно, чтобы имя отражало предназначение шаблона.




Закладка «Шаблоны URL». Добавляем новый шаблон. Задаем ему имя. Имя может быть любым. Желательно, чтобы имя отражало предназначение шаблона



В шаблоне добавляем метод. В данном методе будем программный код шаблона.





Функция ШаблонURL1ПолучитьДанныеПоНоменклатуре(Запрос)

Ответ = Новый HTTPСервисОтвет(200);

СтрокаJSON = ОбщегоНазначения.ПолучитьНоменклатуру();

Ответ.УстановитьТелоИзСтроки(СтрокаJSON);

Возврат Ответ;


КонецФункции

**Публикация http сервиса**

ВАЖНО, НА ВАШЕМ КОМПЬЮТЕРЕ УЖЕ ДОЛЖЕН БЫТЬ УСТАНОВЛЕН ВЕБ СЕРВЕР (APACHE (2.2 ИЛИ 2.4) ИЛИ ISS)


Запускаем конфигуратор 1С: Предприятия 8 в режиме «Запуск от имени администратора»

Главное меню Администрирование – Публикация на веб-сервере




Закладка «Основные» поле имя. Необходимо задать имя. Имя должно быть сформировано по правилу формирования имен переменных. Имя не должно содержать русских букв.

Закладка «Основные» поле «Каталог». Создаем на жестком диске каталог (например, www) и указываем к нему путь. В данный каталог будет размещена публикация.



Закладка «Основные» - закладка «HTTP сервисы». Устанавливаем флаг около нашего сервиса. Нажимаем кнопку «Опубликовать». Перезапускаем веб сервер.




**Проверка работы http сервиса.**


Запускаем браузер.

Прописываем в строке браузера ip адрес компьютера на котором работает веб сервис (в нашем случае это наша локальная машина)

После этого если веб сервер запущен, мы должны увидеть в браузере соответствующее сообщение.




Если все нормально, в строке браузера прописываем путь к нашему сервису по определенному правилу




Рассмотрим более подробно формирования строки запроса в строке адреса браузера

localhost/my\_name/hs/products/get\_product

localhost – ip адрес веб сервера. Если запускаем браузер с той же машины где установлен веб сервер то ip адрес либо localhost либо 127.0.0.1 либо 192.168.XXX.XXX





Таким образом получаем формулу по которой собираем адрес

**Ip адрес / имя публикации / hs / корневой каталог / шаблон/**

Видео инструкция по созданию http сервиса

<https://youtu.be/5g4-1F4u3Ms>

**2) Разберем вопрос о том, как передавать параметры в http сервис.**

Для чего это может быть нужно. Например, нам нужно получить информацию не о всей номенклатуре, а только о той номенклатуре, у которой определенный штрих код.

**Цель: научиться передавать параметр в http сервис.**

Итак, начнем.

-Откроем ветку «Общие» - «HTTP сервисы»


-Откроем http сервис «ОперацииСНоменклатурой»

-Перейдем на закладку «Шаблоны»

-Добавим новый шаблон. Назовем его «ИзучениеПередачиПараметров»

-Придумаем шаблон, например, «get\_products\_barcode»

До этого момента мы с вами повторили действия предыдущего занятия.




Перейдем к передаче параметров. Параметры в http сервисе, заключены в фигурные скобки. Например,  {beginDate} или {articul} или {} еще что-то.

Как можно предположить параметр {beginDate} – это какая-то начальная дата, параметр {articul} – это артикул. ИТАК, ПАРАМЕТРЫ В HTTP ЗАПРОСЕ ЗАКЛЮЧЕНЫ В ФИГУРНЫЕ СКОБКИ - {SOME\_PARAMETER} - имя какого-то параметра. В нашей задаче нам нужен параметр штрих код. Таким образом мы его должны записать в фигурных скобках, вот так {barcode}. ПАРАМЕТРЫ ДОЛЖНЫ БЫТЬ НАЗВАНЫ ЛАТИНСКИМИ БУКВАМИ ПО ПРАВИЛУ СОЗДАНИЯ ИМЕН ПЕРЕМЕННЫХ.

Замечательно. Но куда этот параметр деть, куда его приложить?

А вот куда. Мы придумали имя шаблона «get\_products\_barcode», так вот после него и записывается параметр вот так, /get\_products\_barcode/{barcode}. Мы в шаблоне указали параметр.



//////////////////////////////////////////////////////

-В общем модуле «ОбщегоНазначения» создадим новую функцию, которая будет возвращать JSON строку с данными по номенклатуре, в зависимости от параметра штрих кода.

Функция будет называться «ПолучитьНоменклатуруПоШтрихкоду»

**Эта функция находится в ОбщиеМодули - ОбщегоНазначения**

Функция ПолучитьНоменклатуруПоШтрихкоду(Штрихкод)Экспорт

Запрос = Новый Запрос;

Запрос.УстановитьПараметр("Штрихкод", Штрихкод);

Запрос.Текст =

"ВЫБРАТЬ

| Штрихкоды.Штрихкод КАК barcode,

| Штрихкоды.Номенклатура.Код КАК cod,

| Штрихкоды.Номенклатура.Наименование КАК name,

| Штрихкоды.Номенклатура.Артикул КАК articul

|ИЗ

| РегистрСведений.Штрихкоды КАК Штрихкоды

|ГДЕ

| Штрихкоды.Штрихкод = &Штрихкод";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Массив = Новый Массив;

Пока Выборка.Следующий()Цикл

Структура = Новый Структура("barcode, cod, name, articul");

ЗаполнитьЗначенияСвойств(Структура, Выборка);

Массив.Добавить(Структура);

КонецЦикла;

ЗаписьJSON = Новый ЗаписьJSON;

ЗаписьJSON.УстановитьСтроку();


ЗаписатьJSON(ЗаписьJSON, Массив);

СтрокаJSON = ЗаписьJSON.Закрыть();


Возврат СтрокаJSON;

КонецФункции

-В модуле http сервиса «ОперацииСНоменклатурой» - шаблон «ИзучениеПередачиПараметров» добавляем метод «ПолучитьНоменклатуруПоШтрихкоду». Далее переходим в модуль http сервиса и описываем код, который принимает параметр из Http запроса.



**Данная функция находится тут**



Функция ИзучениеПередачиПараметровПолучитьНоменклатуруПоШтрихкоду(Запрос)

Ответ = Новый HTTPСервисОтвет(200);

Штрихкод = Запрос.ПараметрыURL["barcode"];

СтрокаJSON = ОбщегоНазначения.ПолучитьНоменклатуруПоШтрихкоду(Штрихкод);


Ответ.УстановитьТелоИзСтроки(СтрокаJSON,КодировкаТекста.UTF8,ИспользованиеByteOrderMark.Использовать);

Возврат Ответ;

КонецФункции

-Опубликовываем http сервис «ОперацииСНоменклатурой»

**Меню - Администрирование - Публикация на веб-сервере**





-Открываем браузер и собираем строку запроса. Как мы помним из прошлого урока строка собирается так:

Ip адрес / имя\_публикации / hs / корневой\_каталог / шаблон/{параметр}

localhost/my\_name/hs/products/get\_products/{barcode} – ТОЛЬКО ВМЕСТО ФИГУРНЫХ СКОБОК, КОНКРЕТНОЕ ЗНАЧЕНИЕ ШТРИХ КОДА, НАПРИМЕР 20000000583067

localhost/my\_name/hs/products/get\_products/20000000583067





**Видео инструкция по передаче параметров в http сервис.**

<https://youtu.be/i8V-SnGhMcE>

**4) Передача нескольких параметров в http сервис, a также формирование сложных JSON строк.**

На прошлых уроках [**Учимся создавать http-сервисы (часть первая)**](https://infostart.ru/1c/articles/1293341/) , [**Учимся создавать http сервисы (часть вторая). Передача параметра в http сервис**](https://infostart.ru/1c/articles/1296740/) , мы с вами научились создавать http  сервис, научились передавать один параметр в сервис. Сегодня мы разберем вопрос о том, как передавать несколько параметров в http сервис, а так-же немного поработаем с формированием JSON строки.

**Цель:**

**-Научится передавать сколько угодно параметров в http сервис.**

**-Научится собирать сложные JSON строки.**

Прежде чем начнем разбирать вопрос по передаче параметров, подготовим несколько объектов метаданных для демонстрации.

-Добавим справочник «Склады»

-Добавим справочник «Контрагенты»

-Добавим документ «РеализацияТоваровУслуг»

Реквизиты шапки:

-Контрагент (спр. Ссылка «Контрагенты»)

-Склад (спр. Ссылка «Склады»)

Табличная часть «Товары»


Реквизиты табличной части:

-Номенклатура (спр. «Номенклатура»)

-Цена (Число 15,2)




-Количество (Число 15,3)


-Сумма (Число 15,3)



Сохраним все изменения и обновим конфигурацию базы данных.

Зайдем в режим предприятия и добавим несколько складов, контрагентов и документов.





**Постановка задачи:**


Необходимо получить документы в JSON формате за период с Даты1 по Дата2.

Из задачи следует, что нам нужно передать два параметра в http запрос, начальную дату и конечную дату.

-Откроем ветку «Общие» - «HTTP сервисы»

-Создадим новый http сервис «РаботаСДокументами»

-Установим корневой URL – documents




-Перейдем на закладку «ШаблоныURL»

-***Добавим новый шаблон «ПолучитьРасходныеДокументыЗаПериод». Настроим шаблон /get\_documents\_from\_date\_to\_date/. Как помним из второго урока, параметры записываются в фигурных скобках, установим параметр /get\_documents\_from\_date\_to\_date/{beginDate}. Установили первый параметр. Установим второй параметр /get\_documents\_from\_date\_to\_date/{beginDate}/{endDate}. Таким образом мы установили два параметра.***


***Можно было уставить их немного по другому, добавить дополнительное пояснение в шаблоне, о том что это за параметры, например так: /get\_documents\_from\_date\_to\_date/beginDate/{beginDate}/endDate/{endDate}.***

***Давайте в нашей задаче остановимся на первом варианте.***

***Итак мы имеем шаблон: /get\_documents\_from\_date\_to\_date/{beginDate}/{endDate}. Таким образом мы научились передавать два параметра в http запрос.***



-Добавим новый метод «ПолучитьДокументы»



-Перейдем в обработчик

-Получим значения параметра {beginDate} и {endDate} (если забыли, смотрим вторую часть [infostart.ru/1c/articles/1296740/](https://infostart.ru/1c/articles/1296740/))

-Преобразуем наши параметры в тип «Дата», при помощи функции Дата()

Функция ПолучитьРасходныеДокументыЗаПериодПолучитьДокументы(Запрос)

Ответ = Новый HTTPСервисОтвет(200);

НачальнаяДатаСтрока = Запрос.ПараметрыURL["beginDate"];

КонечнаяДатаСтрока = Запрос.ПараметрыURL["endDate"];

НачальнаяДата = Дата(НачальнаяДатаСтрока);

КонечнаяДата = Дата(КонечнаяДатаСтрока);

Возврат Ответ;

КонецФункции

-Перейдем в общий модуль «ОбщегоНазначения» и в нем напишем функцию «ПолучитьJSONСтрокуДокументов», которая возвращаем json строку – информацию по документам.

Функция ПолучитьJSONСтрокуДокументов(НачалоПериода, КонецПериода)экспорт

запрос = Новый Запрос;

Запрос.УстановитьПараметр("НачалоПериода", НачалоПериода);

Запрос.УстановитьПараметр("КонецПериода", КонецДня(КонецПериода));

запрос.Текст =

"ВЫБРАТЬ

| РеализацияТоваровУслугТовары.Ссылка КАК Ссылка,

| РеализацияТоваровУслугТовары.Номенклатура КАК Номенклатура,

| РеализацияТоваровУслугТовары.Количество КАК Количество,

| РеализацияТоваровУслугТовары.Сумма КАК Сумма,

| РеализацияТоваровУслугТовары.Номенклатура.Наименование КАК НоменклатураНаименование

|ИЗ

| Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары

|ГДЕ

| РеализацияТоваровУслугТовары.Ссылка.Проведен

| И РеализацияТоваровУслугТовары.Ссылка.Дата МЕЖДУ &НачалоПериода И &КонецПериода

|ИТОГИ ПО

| Ссылка";

результат = запрос.Выполнить();

выборкаСсылка = результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "Ссылка");

массив = новый Массив;

пока выборкаСсылка.Следующий()цикл

структураДок = Новый Структура;

структураДок.Вставить("номер", выборкаСсылка.Ссылка.Номер);

структураДок.Вставить("дата", выборкаСсылка.Ссылка.дата);

структураДок.Вставить("id", строка(выборкаСсылка.Ссылка.УникальныйИдентификатор()));

выборка = выборкаСсылка.Выбрать();

массивТовары = новый Массив;

пока выборка.Следующий()цикл

структураТовары = новый Структура;

структураТовары.Вставить("id\_товара", строка(выборка.номенклатура.УникальныйИдентификатор()));

структураТовары.Вставить("наименование", выборка.НоменклатураНаименование);

структураТовары.Вставить("количество", выборка.Количество);

структураТовары.Вставить("сумма", выборка.сумма);

массивТовары.Добавить(структураТовары);

конецЦикла;

структураДок.Вставить("Товары", массивТовары);

массив.Добавить(структураДок);

конецЦикла;

структура = новый Структура("Документы");

структура.документы = массив;

записьJSON = новый ЗаписьJSON();

записьJSON.УстановитьСтроку();

ЗаписатьJSON(записьJSON, структура, новый НастройкиСериализацииJSON ,"ФункцияПреобразованияЗаписи");

сериализованнаяСтрока = записьJSON.Закрыть();

возврат сериализованнаяСтрока;

КонецФункции

Функция ФункцияПреобразованияЗаписи(Свойство, Значение, ДополнительныеПараметры, Отказ)

Если ТипЗнч(Значение) = Тип("УникальныйИдентификатор") Тогда

Возврат Строка(Значение);

КонецЕсли;

Отказ = Истина;

КонецФункции

-Вызываем эту функцию из обработчика и передаем в нее два параметра НачалоПериода и КонецПериода.

-JSON строку устанавливаем в «Ответ»

Функция ПолучитьРасходныеДокументыЗаПериодПолучитьДокументы(Запрос)

Ответ = Новый HTTPСервисОтвет(200);

НачальнаяДатаСтрока = Запрос.ПараметрыURL["beginDate"];

КонечнаяДатаСтрока = Запрос.ПараметрыURL["endDate"];

НачальнаяДата = Дата(НачальнаяДатаСтрока);

КонечнаяДата = Дата(КонечнаяДатаСтрока);

СтрокаJSON = ОбщегоНазначения.ПолучитьJSONСтрокуДокументов(НачальнаяДата, КонечнаяДата);

Ответ.УстановитьТелоИзСтроки(СтрокаJSON,КодировкаТекста.UTF8,ИспользованиеByteOrderMark.Использовать);


Возврат Ответ;

КонецФункции

-Публикуем http сервис. Запускаем программу 1С из под администратора. Меню Администрирование – Публикация на веб сервере. Публикуем http сервис. Подробное описание тут [infostart.ru/1c/articles/1293341/](https://infostart.ru/1c/articles/1293341/)

-Открываем браузер. Собираем строку подключения с параметрами. В моем случае эта строка будет иметь такой вид: [http://localhost/my\_name/hs/documents/get\_documents\_from\_date\_to\_date/20201001/20201002](https://infostart.ru/redirect.php?url=aHR0cDovL2xvY2FsaG9zdC9teV9uYW1lL2hzL2RvY3VtZW50cy9nZXRfZG9jdW1lbnRzX2Zyb21fZGF0ZV90b19kYXRlLzIwMjAxMDAxLzIwMjAxMDAy)

-В браузере проверяем результат. Должны увидеть json строку, которую мы сформировали.



На этом уроке мы научились передавать два параметра в http сервис.

Аналогично можно передавать множество параметров, по шаблону

**Ip адрес / Имя публикации / hs / корневой каталог / шаблон / {Параметр1}/{Параметр2}/ … / {Параметр N}.**

**5)** Запросы, которые, до сих пор отправляли на сервер, были GET запросами. **При помощи метода GET запроса можно получать данные с сервера**. Мы, например, получали информацию о документах расходных документах, а также, получали информацию о номенклатуре.

**Что делать, если нам нужно передать некие данные на сервер?** На помощь приходит http запрос типа ***POST***!

**Поставим задачу:**

**-Перенесем данные справочника «Номенклатура» из базы источник в базу приемник при помощи http сервиса, используя POST запрос. Переносить данные будем в JSON формате.**

**Подготовим базу источник.**

-Создаем чистую информационную базу.


-Назовем ее «БазаИсточник»

-Добавляем в нее несколько объектом метаданных:

*Спр. «Номенклатура»*

Реквизит «Атрикул» тип строка 25

-Обработка «ИзучениеPOSTЗапросов»



**Подготовим базу приемник**

-Создаем чистую информационную базу

-Назовем ее «БазаПриемник»


-Добавим в нее несколько объектов метаданных:

*Спр. «Номенклатура»*

Реквизит «Атрикул» тип строка 25

-Создаем новый http сервис «ИзучениеPOSTЗапросов»

-Корневой URL – «post»




-Переходим на закладку «Шаблоны URL»


-Добавляем новый шаблон «ЗагрузкаНоменклатуры»

-Создадим шаблон, назовем его «product\_json»

-Добавим новый метод «ЗагрузкаНоменклатурыJSON»

-**Выбираем HTTP метод POST**





-Публикуем http сервис на веб сервере, если забыли, как это сделать, смотрите статью

[***Учимся создавать http-сервисы (часть первая)***](https://infostart.ru/1c/articles/1293341/)

После публикации у меня получился следующий путь «http://localhost/post\_test/hs/post/product\_json/»

Localhost – IP адрес

post\_test – имя публикации

hs – признак http сервиса


post – корневой каталог

product\_json - шаблон

**Переходим в базу источник.**

-Открываем обработку «ИзучениеPOSTЗапросов»

-Создадим форму. На форме разместим кнопку «Перенести номенклатуру JSON»



**Шаблон, по которому мы подключаемся из 1С к http сервису следующий:**

-Создаем объект типа «HTTPСоединение», в его конструкторе передаем ip адрес http сервиса, например, так:

Сервер = "localhost";

Попытка

Соединение = Новый HTTPСоединение(Сервер);

Исключение

Сообщение.Текст = ОписаниеОшибки();

Сообщение.Сообщить();

Возврат;

КонецПопытки;

-Создаем объект типа «HTTPЗапрос», в его конструкторе указываем адрес ресурса и заголовки, например так:

АдресРесурса = "/post\_test/hs/post/product\_json/";

Заголовки = Новый Соответствие;

Заголовки.Вставить("Content-Type", "text/plain;charset=UTF-8");

HTTPЗапрос = Новый HTTPЗапрос(АдресРесурса, Заголовки);

-Помещаем данные, которые мы хотим отправить на сервер в тело запроса. Мы хотим передать текстовые данные, для этого мы воспользуемся методом «УстановитьТелоИзСтроки»

-Отправляем данные на сервер. (пример кода)

&НаСервере

Функция ПолучитьJSONСтрокуНоменклатуры()

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| Номенклатура.Код КАК Код,

| Номенклатура.Наименование КАК Наименование,

| Номенклатура.Артикул КАК Артикул

|ИЗ

| Справочник.Номенклатура КАК Номенклатура";

результат = запрос.Выполнить();

Выборка = результат.Выбрать();

массив = новый Массив;

пока Выборка.Следующий()цикл

Структура = Новый Структура;

Структура.Вставить("Код", Выборка.Код);

Структура.Вставить("Наименование", Выборка.Наименование);

Структура.Вставить("Артикул", Выборка.Артикул);

массив.Добавить(Структура);

конецЦикла;

ЗаписьJSON = новый ЗаписьJSON();

ЗаписьJSON.УстановитьСтроку();

ЗаписатьJSON(ЗаписьJSON, Массив);

сериализованнаяСтрока = ЗаписьJSON.Закрыть();

возврат сериализованнаяСтрока;

КонецФункции

&НаКлиенте

Процедура ПеренестиНоменклатуруJSON(Команда)

//Шаблон

Сообщение = Новый СообщениеПользователю;

Сервер = "localhost";

Попытка

Соединение = Новый HTTPСоединение(Сервер);

Исключение

Сообщение.Текст = ОписаниеОшибки();

Сообщение.Сообщить();

Возврат;

КонецПопытки;

АдресРесурса = "/post\_test/hs/post/product\_json/";

Заголовки = Новый Соответствие;

//ОТВЕЧАЕТ ЗА ТИП ДАННЫХ КОТОРЫЕ БУДУТ УСТАНОВЛЕНЫ В ТЕЛО ЗАПРОСА

Заголовки.Вставить("Content-Type", "text/plain;charset=UTF-8");

HTTPЗапрос = Новый HTTPЗапрос(АдресРесурса, Заголовки);

//Получаем строку JSON с данными по номенклатуре

СтрокаНоменклатураJSON = ПолучитьJSONСтрокуНоменклатуры();

//УСТАНАВЛИВАЕМ ТЕЛО ЗАПРОСА

HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаНоменклатураJSON);

Попытка

//ОТПРАВЛЯЕМ ДАННЫЕ НА СЕРВЕР

Соединение.ОтправитьДляОбработки(HTTPЗапрос);

Исключение

Сообщение.Текст = ОписаниеОшибки();

Сообщение.Сообщить();


Возврат;

КонецПопытки;

КонецПроцедуры

***Еще раз. Для того чтобы передать данные на сервер, надо эти данные поместить в тело POST запроса. В заголовке необходимо указать какого типа эти данные.***

-Открываем базу источник в режиме предприятия и добавляем в справочник «Номенклатура» несколько элементов.



Базу источник мы подготовили!

**Переходим в базу приемник**

-Добавляем общий модуль «ОбщегоНазначения»

-В нем описываем две процедуры

//ПАРСИМ JSON СТРОКУ

Процедура ЗагрузитьНоменклатуруJSON(СтрокаJSON)Экспорт

ЧтениеJSON = Новый ЧтениеJSON();

ЧтениеJSON.УстановитьСтроку(СтрокаJSON);

НоменклатураМассив = ПрочитатьJSON(ЧтениеJSON);

Для Каждого СтрокаМассива Из НоменклатураМассив Цикл

СоздатьНоменклатуру(СтрокаМассива);

КонецЦикла;

КонецПроцедуры

//СОЗДАЕМ ЭЛЕМЕНТЫ СПРАВОЧНИКА НОМЕНКЛАТУРА

Процедура СоздатьНоменклатуру(СтруктураСДанными)

НоменклатураОбъект = Справочники.Номенклатура.СоздатьЭлемент();

НоменклатураОбъект.Код = СтруктураСДанными.Код;

НоменклатураОбъект.Наименование = СтруктураСДанными.Наименование;

НоменклатураОбъект.Артикул = СтруктураСДанными.Артикул;

НоменклатураОбъект.Записать();

КонецПроцедуры

-Переходим в обработчик метода «ЗагрузкаНоменклатурыJSON» http сервиса «ИзучениеPOSTЗапросов»

-Описываем в нем следующий код

Функция ШаблонURL1ЗагрузкаНоменклатурыJSON(Запрос)

Ответ = Новый HTTPСервисОтвет(200);

//ПОЛУЧАЕМ ДАННЫЕ ИЗ ТЕЛА ЗАПРОСА

СтрокаНоменклатураJSON = Запрос.ПолучитьТелоКакСтроку();

//ПЕРЕДАЕМ ДАННЫЕ (JSON СТРОКУ)В ОБЩИЙ МОДУЛЬ ДЛЯ СОЗДАНИЯ НОМЕНКЛАТУРЫ



ОбщегоНазначения.ЗагрузитьНоменклатуруJSON(СтрокаНоменклатураJSON);

Возврат Ответ;

КонецФункции

**Базу приемник мы подготовили.**

Запускаем обработку из базы источник. Нажимаем на кнопку. И в базе приемнике создается номенклатура.



Видео инструкция тут:

[**https://youtu.be/A7hhdckFfY8**](https://youtu.be/A7hhdckFfY8)